feat: update flake and hosts for new structure

flake/devshell.nix

@@ -0,0 +1,17 @@
+_: {
+  perSystem =
+    { pkgs, ... }:
+    {
+      formatter = pkgs.nixfmt-tree;
+
+      devShells.default = pkgs.mkShell {
+        packages = [
+          pkgs.pre-commit
+          pkgs.statix
+          pkgs.shellcheck
+          pkgs.shfmt
+          pkgs.qemu
+        ];
+      };
+    };
+}

flake/hosts.nix

@@ -0,0 +1,86 @@
+{ inputs, self, ... }:
+
+let
+  inherit (inputs) nixpkgs;
+  my-lib = import ../lib { inherit (nixpkgs) lib; };
+
+  mkHost = my-lib.mkHost {
+    inherit nixpkgs inputs;
+    overlays = [ self.overlays.default ];
+  };
+in
+{
+  flake.nixosConfigurations = {
+    fw16 = mkHost "fw16" {
+      system = "x86_64-linux";
+      user = "matej";
+      features = [
+        "openssh"
+        "localisation"
+        "gnupg"
+        "shell"
+        "desktop"
+        "sway"
+        "greeter"
+        "printing"
+        "networkmanager"
+        "docker"
+        "tailscale"
+        "nix-ld"
+        "yubikey"
+        "calibre"
+        "steam"
+        "neovim"
+        "dev"
+        "claude"
+      ];
+    };
+
+    tower = mkHost "tower" {
+      system = "x86_64-linux";
+      user = "matej";
+      features = [
+        "openssh"
+        "localisation"
+        "gnupg"
+        "shell"
+        "desktop"
+        "sway"
+        "greeter"
+        "printing"
+        "networkmanager"
+        "docker"
+        "tailscale"
+        "yubikey"
+        "calibre"
+        "initrd-ssh"
+        "neovim"
+        "dev"
+        "claude"
+      ];
+    };
+
+    # nixos-rebuild build-image --image-variant install-iso --flake .#iso
+    iso = mkHost "iso" {
+      system = "x86_64-linux";
+      features = [
+        "openssh"
+      ];
+    };
+
+    ephvm = mkHost "ephvm" {
+      system = "x86_64-linux";
+      user = "matej";
+      features = [
+        "openssh"
+        "localisation"
+        "gnupg"
+        "shell"
+        "vm-guest"
+        "vm-9p-automount"
+        "docker"
+        "neovim"
+      ];
+    };
+  };
+}

flake/overlays.nix

@@ -0,0 +1,21 @@
+{ inputs, ... }:
+
+{
+  flake.overlays.default =
+    _: prev:
+    let
+      pkgs-unstable = import inputs.nixpkgs-unstable {
+        inherit (prev.stdenv.hostPlatform) system;
+        inherit (prev) config;
+      };
+      pkgs-master = import inputs.nixpkgs-master {
+        inherit (prev.stdenv.hostPlatform) system;
+        inherit (prev) config;
+      };
+    in
+    {
+      inherit (pkgs-master) claude-code;
+      # TODO:(@janezicmatej) 2026-03-09 error with stable for telegram-desktop
+      inherit (pkgs-unstable) telegram-desktop;
+    };
+}

flake/packages.nix

@@ -0,0 +1,22 @@
+{ inputs, ... }:
+
+let
+  my-lib = import ../lib { inherit (inputs.nixpkgs) lib; };
+in
+{
+  perSystem =
+    { pkgs, system, ... }:
+    {
+      packages =
+        import ../packages
+          {
+            inherit my-lib;
+            inherit (inputs.nixpkgs) lib;
+          }
+          {
+            inherit pkgs;
+            pkgs-unstable = inputs.nixpkgs-unstable.legacyPackages.${system};
+            pkgs-master = inputs.nixpkgs-master.legacyPackages.${system};
+          };
+    };
+}